mirror of
https://github.com/torvalds/linux.git
synced 2024-11-22 04:18:58 +00:00
de5f398466
Now that the minimum supported version of LLVM for building the kernel has
been bumped to 13.0.1, the condition for using _mcount as MCOUNT_NAME is
always true, as the build will fail during the configuration stage for
older LLVM versions. Replace MCOUNT_NAME with _mcount directly.
This effectively reverts commit 7ce0477150 ("riscv: Workaround mcount
name prior to clang-13").
Link: https://lkml.kernel.org/r/20240125-bump-min-llvm-ver-to-13-0-1-v1-7-f5ff9bda41c5@kernel.org
Signed-off-by: Nathan Chancellor <nathan@kernel.org>
Reviewed-by: Kees Cook <keescook@chromium.org>
Cc: Albert Ou <aou@eecs.berkeley.edu>
Cc: "Aneesh Kumar K.V (IBM)" <aneesh.kumar@kernel.org>
Cc: Ard Biesheuvel <ardb@kernel.org>
Cc: Borislav Petkov (AMD) <bp@alien8.de>
Cc: Catalin Marinas <catalin.marinas@arm.com>
Cc: Conor Dooley <conor@kernel.org>
Cc: Dave Hansen <dave.hansen@linux.intel.com>
Cc: Ingo Molnar <mingo@redhat.com>
Cc: Mark Rutland <mark.rutland@arm.com>
Cc: Masahiro Yamada <masahiroy@kernel.org>
Cc: Michael Ellerman <mpe@ellerman.id.au>
Cc: "Naveen N. Rao" <naveen.n.rao@linux.ibm.com>
Cc: Nicholas Piggin <npiggin@gmail.com>
Cc: Nicolas Schier <nicolas@fjasle.eu>
Cc: Palmer Dabbelt <palmer@dabbelt.com>
Cc: Paul Walmsley <paul.walmsley@sifive.com>
Cc: Russell King <linux@armlinux.org.uk>
Cc: Thomas Gleixner <tglx@linutronix.de>
Cc: Will Deacon <will@kernel.org>
Signed-off-by: Andrew Morton <akpm@linux-foundation.org>
132 lines
2.8 KiB
ArmAsm
132 lines
2.8 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/* Copyright (C) 2017 Andes Technology Corporation */
|
|
|
|
#include <linux/init.h>
|
|
#include <linux/linkage.h>
|
|
#include <linux/cfi_types.h>
|
|
#include <linux/export.h>
|
|
#include <asm/asm.h>
|
|
#include <asm/csr.h>
|
|
#include <asm/unistd.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/ftrace.h>
|
|
|
|
.text
|
|
|
|
.macro SAVE_ABI_STATE
|
|
addi sp, sp, -16
|
|
REG_S s0, 0*SZREG(sp)
|
|
REG_S ra, 1*SZREG(sp)
|
|
addi s0, sp, 16
|
|
.endm
|
|
|
|
/*
|
|
* The call to ftrace_return_to_handler would overwrite the return
|
|
* register if a0 was not saved.
|
|
*/
|
|
.macro SAVE_RET_ABI_STATE
|
|
addi sp, sp, -4*SZREG
|
|
REG_S s0, 2*SZREG(sp)
|
|
REG_S ra, 3*SZREG(sp)
|
|
REG_S a0, 1*SZREG(sp)
|
|
REG_S a1, 0*SZREG(sp)
|
|
addi s0, sp, 4*SZREG
|
|
.endm
|
|
|
|
.macro RESTORE_ABI_STATE
|
|
REG_L ra, 1*SZREG(sp)
|
|
REG_L s0, 0*SZREG(sp)
|
|
addi sp, sp, 16
|
|
.endm
|
|
|
|
.macro RESTORE_RET_ABI_STATE
|
|
REG_L ra, 3*SZREG(sp)
|
|
REG_L s0, 2*SZREG(sp)
|
|
REG_L a0, 1*SZREG(sp)
|
|
REG_L a1, 0*SZREG(sp)
|
|
addi sp, sp, 4*SZREG
|
|
.endm
|
|
|
|
SYM_TYPED_FUNC_START(ftrace_stub)
|
|
#ifdef CONFIG_DYNAMIC_FTRACE
|
|
.global _mcount
|
|
.set _mcount, ftrace_stub
|
|
#endif
|
|
ret
|
|
SYM_FUNC_END(ftrace_stub)
|
|
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
SYM_TYPED_FUNC_START(ftrace_stub_graph)
|
|
ret
|
|
SYM_FUNC_END(ftrace_stub_graph)
|
|
|
|
SYM_FUNC_START(return_to_handler)
|
|
/*
|
|
* On implementing the frame point test, the ideal way is to compare the
|
|
* s0 (frame pointer, if enabled) on entry and the sp (stack pointer) on return.
|
|
* However, the psABI of variable-length-argument functions does not allow this.
|
|
*
|
|
* So alternatively we check the *old* frame pointer position, that is, the
|
|
* value stored in -16(s0) on entry, and the s0 on return.
|
|
*/
|
|
SAVE_RET_ABI_STATE
|
|
mv a0, sp
|
|
call ftrace_return_to_handler
|
|
mv a2, a0
|
|
RESTORE_RET_ABI_STATE
|
|
jalr a2
|
|
SYM_FUNC_END(return_to_handler)
|
|
#endif
|
|
|
|
#ifndef CONFIG_DYNAMIC_FTRACE
|
|
SYM_FUNC_START(_mcount)
|
|
la t4, ftrace_stub
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
la t0, ftrace_graph_return
|
|
REG_L t1, 0(t0)
|
|
bne t1, t4, .Ldo_ftrace_graph_caller
|
|
|
|
la t3, ftrace_graph_entry
|
|
REG_L t2, 0(t3)
|
|
la t6, ftrace_graph_entry_stub
|
|
bne t2, t6, .Ldo_ftrace_graph_caller
|
|
#endif
|
|
la t3, ftrace_trace_function
|
|
REG_L t5, 0(t3)
|
|
bne t5, t4, .Ldo_trace
|
|
ret
|
|
|
|
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
|
|
/*
|
|
* A pseudo representation for the function graph tracer:
|
|
* prepare_to_return(&ra_to_caller_of_caller, ra_to_caller)
|
|
*/
|
|
.Ldo_ftrace_graph_caller:
|
|
addi a0, s0, -SZREG
|
|
mv a1, ra
|
|
#ifdef HAVE_FUNCTION_GRAPH_FP_TEST
|
|
REG_L a2, -2*SZREG(s0)
|
|
#endif
|
|
SAVE_ABI_STATE
|
|
call prepare_ftrace_return
|
|
RESTORE_ABI_STATE
|
|
ret
|
|
#endif
|
|
|
|
/*
|
|
* A pseudo representation for the function tracer:
|
|
* (*ftrace_trace_function)(ra_to_caller, ra_to_caller_of_caller)
|
|
*/
|
|
.Ldo_trace:
|
|
REG_L a1, -SZREG(s0)
|
|
mv a0, ra
|
|
|
|
SAVE_ABI_STATE
|
|
jalr t5
|
|
RESTORE_ABI_STATE
|
|
ret
|
|
SYM_FUNC_END(_mcount)
|
|
#endif
|
|
EXPORT_SYMBOL(_mcount)
|